/*
 *  Copyright 2023 Alexey Andreev.
 *
 *  Licensed under the Apache License, Version 2.0 (the "License");
 *  you may not use this file except in compliance with the License.
 *  You may obtain a copy of the License at
 *
 *       http://www.apache.org/licenses/LICENSE-2.0
 *
 *  Unless required by applicable law or agreed to in writing, software
 *  distributed under the License is distributed on an "AS IS" BASIS,
 *  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 *  See the License for the specific language governing permissions and
 *  limitations under the License.
 */

plugins {
    `java-library`
    shadowApply
    `teavm-publish`
}

description = "Command line tools"

dependencies {
    implementation(project(":tools:core"))
    implementation(project(":tools:devserver"))
    implementation(project(":tools:c-incremental"))
    implementation(libs.commons.cli)

    runtimeOnly(project(":classlib"))
    runtimeOnly(project(":metaprogramming:impl"))
    runtimeOnly(project(":jso:impl"))
}

tasks {
    shadowJar {
        mergeServiceFiles()
        manifest {
            attributes(
                    "Main-Class" to "org.teavm.cli.TeaVMRunner"
            )
        }
    }
    assemble {
        dependsOn(shadowJar)
    }
}

teavmPublish {
    artifactId = "teavm-cli"
}

components.configureEach {
    if (name == "java") {
        val config = configurations.getByName("shadowRuntimeElements")
        (this as AdhocComponentWithVariants).withVariantsFromConfiguration(config) {
            skip()
        }
    }
}