256 lines
10 KiB
GLSL
Executable File
256 lines
10 KiB
GLSL
Executable File
#line 0
|
|
|
|
precision lowp int;
|
|
precision lowp sampler2D;
|
|
precision lowp float;
|
|
|
|
in vec2 pos;
|
|
|
|
out vec4 fragColor;
|
|
|
|
#define FXAA_PC 1
|
|
#define FXAA_GLSL_130 1
|
|
#define FXAA_FAST_PIXEL_OFFSET 0
|
|
#define FXAA_GATHER4_ALPHA 0
|
|
|
|
#ifndef FXAA_GREEN_AS_LUMA
|
|
// For those using non-linear color,
|
|
// and either not able to get luma in alpha, or not wanting to,
|
|
// this enables FXAA to run using green as a proxy for luma.
|
|
// So with this enabled, no need to pack luma in alpha.
|
|
//
|
|
// This will turn off AA on anything which lacks some amount of green.
|
|
// Pure red and blue or combination of only R and B, will get no AA.
|
|
//
|
|
// Might want to lower the settings for both,
|
|
// fxaaConsoleEdgeThresholdMin
|
|
// fxaaQualityEdgeThresholdMin
|
|
// In order to insure AA does not get turned off on colors
|
|
// which contain a minor amount of green.
|
|
//
|
|
// 1 = On.
|
|
// 0 = Off.
|
|
//
|
|
#define FXAA_GREEN_AS_LUMA 1
|
|
#endif
|
|
|
|
#ifndef FXAA_DISCARD
|
|
// 1 = Use discard on pixels which don't need AA.
|
|
// 0 = Return unchanged color on pixels which don't need AA.
|
|
#define FXAA_DISCARD 0
|
|
#endif
|
|
|
|
/*============================================================================
|
|
API PORTING
|
|
============================================================================*/
|
|
#define FxaaBool bool
|
|
#define FxaaDiscard discard
|
|
#define FxaaFloat float
|
|
#define FxaaFloat2 vec2
|
|
#define FxaaFloat3 vec3
|
|
#define FxaaFloat4 vec4
|
|
#define FxaaHalf float
|
|
#define FxaaHalf2 vec2
|
|
#define FxaaHalf3 vec3
|
|
#define FxaaHalf4 vec4
|
|
#define FxaaInt2 ivec2
|
|
#define FxaaSat(x) clamp(x, 0.0, 1.0)
|
|
#define FxaaTex sampler2D
|
|
/*--------------------------------------------------------------------------*/
|
|
|
|
#define FxaaTexTop(t, p) textureLod(t, p, 0.0)
|
|
|
|
/*============================================================================
|
|
GREEN AS LUMA OPTION SUPPORT FUNCTION
|
|
============================================================================*/
|
|
#if (FXAA_GREEN_AS_LUMA == 0)
|
|
// TODO Luma
|
|
FxaaFloat FxaaLuma(FxaaFloat4 rgba) { return dot(rgba.xyz, vec3(0.299, 0.587, 0.114)); }
|
|
#else
|
|
FxaaFloat FxaaLuma(FxaaFloat4 rgba) { return rgba.y; }
|
|
#endif
|
|
|
|
/*============================================================================
|
|
FXAA3 CONSOLE - PC VERSION
|
|
============================================================================*/
|
|
/*--------------------------------------------------------------------------*/
|
|
FxaaFloat4 FxaaPixelShader(
|
|
// See FXAA Quality FxaaPixelShader() source for docs on Inputs!
|
|
//
|
|
// Use noperspective interpolation here (turn off perspective interpolation).
|
|
// {xy} = center of pixel
|
|
FxaaFloat2 pos,
|
|
//
|
|
// Used only for FXAA Console, and not used on the 360 version.
|
|
// Use noperspective interpolation here (turn off perspective interpolation).
|
|
// {xy__} = upper left of pixel
|
|
// {__zw} = lower right of pixel
|
|
FxaaFloat4 fxaaConsolePosPos,
|
|
//
|
|
// Input color texture.
|
|
// {rgb_} = color in linear or perceptual color space
|
|
// if (FXAA_GREEN_AS_LUMA == 0)
|
|
// {___a} = luma in perceptual color space (not linear)
|
|
FxaaTex tex,
|
|
//
|
|
// Only used on FXAA Console.
|
|
// This must be from a constant/uniform.
|
|
// This effects sub-pixel AA quality and inversely sharpness.
|
|
// Where N ranges between,
|
|
// N = 0.50 (default)
|
|
// N = 0.33 (sharper)
|
|
// {x___} = -N/screenWidthInPixels
|
|
// {_y__} = -N/screenHeightInPixels
|
|
// {__z_} = N/screenWidthInPixels
|
|
// {___w} = N/screenHeightInPixels
|
|
FxaaFloat4 fxaaConsoleRcpFrameOpt,
|
|
//
|
|
// Only used on FXAA Console.
|
|
// Not used on 360, but used on PS3 and PC.
|
|
// This must be from a constant/uniform.
|
|
// {x___} = -2.0/screenWidthInPixels
|
|
// {_y__} = -2.0/screenHeightInPixels
|
|
// {__z_} = 2.0/screenWidthInPixels
|
|
// {___w} = 2.0/screenHeightInPixels
|
|
FxaaFloat4 fxaaConsoleRcpFrameOpt2,
|
|
//
|
|
// Only used on FXAA Console.
|
|
// This used to be the FXAA_CONSOLE__EDGE_SHARPNESS define.
|
|
// It is here now to allow easier tuning.
|
|
// This does not effect PS3, as this needs to be compiled in.
|
|
// Use FXAA_CONSOLE__PS3_EDGE_SHARPNESS for PS3.
|
|
// Due to the PS3 being ALU bound,
|
|
// there are only three safe values here: 2 and 4 and 8.
|
|
// These options use the shaders ability to a free *|/ by 2|4|8.
|
|
// For all other platforms can be a non-power of two.
|
|
// 8.0 is sharper (default!!!)
|
|
// 4.0 is softer
|
|
// 2.0 is really soft (good only for vector graphics inputs)
|
|
FxaaFloat fxaaConsoleEdgeSharpness,
|
|
//
|
|
// Only used on FXAA Console.
|
|
// This used to be the FXAA_CONSOLE__EDGE_THRESHOLD define.
|
|
// It is here now to allow easier tuning.
|
|
// This does not effect PS3, as this needs to be compiled in.
|
|
// Use FXAA_CONSOLE__PS3_EDGE_THRESHOLD for PS3.
|
|
// Due to the PS3 being ALU bound,
|
|
// there are only two safe values here: 1/4 and 1/8.
|
|
// These options use the shaders ability to a free *|/ by 2|4|8.
|
|
// The console setting has a different mapping than the quality setting.
|
|
// Other platforms can use other values.
|
|
// 0.125 leaves less aliasing, but is softer (default!!!)
|
|
// 0.25 leaves more aliasing, and is sharper
|
|
FxaaFloat fxaaConsoleEdgeThreshold,
|
|
//
|
|
// Only used on FXAA Console.
|
|
// This used to be the FXAA_CONSOLE__EDGE_THRESHOLD_MIN define.
|
|
// It is here now to allow easier tuning.
|
|
// Trims the algorithm from processing darks.
|
|
// The console setting has a different mapping than the quality setting.
|
|
// This does not apply to PS3,
|
|
// PS3 was simplified to avoid more shader instructions.
|
|
// 0.06 - faster but more aliasing in darks
|
|
// 0.05 - default
|
|
// 0.04 - slower and less aliasing in darks
|
|
// Special notes when using FXAA_GREEN_AS_LUMA,
|
|
// Likely want to set this to zero.
|
|
// As colors that are mostly not-green
|
|
// will appear very dark in the green channel!
|
|
// Tune by looking at mostly non-green content,
|
|
// then start at zero and increase until aliasing is a problem.
|
|
FxaaFloat fxaaConsoleEdgeThresholdMin
|
|
) {
|
|
/*--------------------------------------------------------------------------*/
|
|
FxaaFloat lumaNw = FxaaLuma(FxaaTexTop(tex, fxaaConsolePosPos.xy));
|
|
FxaaFloat lumaSw = FxaaLuma(FxaaTexTop(tex, fxaaConsolePosPos.xw));
|
|
FxaaFloat lumaNe = FxaaLuma(FxaaTexTop(tex, fxaaConsolePosPos.zy));
|
|
FxaaFloat lumaSe = FxaaLuma(FxaaTexTop(tex, fxaaConsolePosPos.zw));
|
|
/*--------------------------------------------------------------------------*/
|
|
FxaaFloat4 rgbyM = FxaaTexTop(tex, pos.xy);
|
|
#if (FXAA_GREEN_AS_LUMA == 0)
|
|
// TODO Luma
|
|
FxaaFloat lumaM = FxaaLuma(rgbyM);
|
|
#else
|
|
FxaaFloat lumaM = rgbyM.y;
|
|
#endif
|
|
/*--------------------------------------------------------------------------*/
|
|
FxaaFloat lumaMaxNwSw = max(lumaNw, lumaSw);
|
|
lumaNe += 1.0/384.0;
|
|
FxaaFloat lumaMinNwSw = min(lumaNw, lumaSw);
|
|
/*--------------------------------------------------------------------------*/
|
|
FxaaFloat lumaMaxNeSe = max(lumaNe, lumaSe);
|
|
FxaaFloat lumaMinNeSe = min(lumaNe, lumaSe);
|
|
/*--------------------------------------------------------------------------*/
|
|
FxaaFloat lumaMax = max(lumaMaxNeSe, lumaMaxNwSw);
|
|
FxaaFloat lumaMin = min(lumaMinNeSe, lumaMinNwSw);
|
|
/*--------------------------------------------------------------------------*/
|
|
FxaaFloat lumaMaxScaled = lumaMax * fxaaConsoleEdgeThreshold;
|
|
/*--------------------------------------------------------------------------*/
|
|
FxaaFloat lumaMinM = min(lumaMin, lumaM);
|
|
FxaaFloat lumaMaxScaledClamped = max(fxaaConsoleEdgeThresholdMin, lumaMaxScaled);
|
|
FxaaFloat lumaMaxM = max(lumaMax, lumaM);
|
|
FxaaFloat dirSwMinusNe = lumaSw - lumaNe;
|
|
FxaaFloat lumaMaxSubMinM = lumaMaxM - lumaMinM;
|
|
FxaaFloat dirSeMinusNw = lumaSe - lumaNw;
|
|
if(lumaMaxSubMinM < lumaMaxScaledClamped)
|
|
{
|
|
#if (FXAA_DISCARD == 1)
|
|
FxaaDiscard;
|
|
#else
|
|
return rgbyM;
|
|
#endif
|
|
}
|
|
/*--------------------------------------------------------------------------*/
|
|
FxaaFloat2 dir;
|
|
dir.x = dirSwMinusNe + dirSeMinusNw;
|
|
dir.y = dirSwMinusNe - dirSeMinusNw;
|
|
/*--------------------------------------------------------------------------*/
|
|
FxaaFloat2 dir1 = normalize(dir.xy);
|
|
FxaaFloat4 rgbyN1 = FxaaTexTop(tex, pos.xy - dir1 * fxaaConsoleRcpFrameOpt.zw);
|
|
FxaaFloat4 rgbyP1 = FxaaTexTop(tex, pos.xy + dir1 * fxaaConsoleRcpFrameOpt.zw);
|
|
/*--------------------------------------------------------------------------*/
|
|
FxaaFloat dirAbsMinTimesC = min(abs(dir1.x), abs(dir1.y)) * fxaaConsoleEdgeSharpness;
|
|
FxaaFloat2 dir2 = clamp(dir1.xy / dirAbsMinTimesC, -2.0, 2.0);
|
|
/*--------------------------------------------------------------------------*/
|
|
FxaaFloat2 dir2x = dir2 * fxaaConsoleRcpFrameOpt2.zw;
|
|
FxaaFloat4 rgbyN2 = FxaaTexTop(tex, pos.xy - dir2x);
|
|
FxaaFloat4 rgbyP2 = FxaaTexTop(tex, pos.xy + dir2x);
|
|
/*--------------------------------------------------------------------------*/
|
|
FxaaFloat4 rgbyA = rgbyN1 + rgbyP1;
|
|
FxaaFloat4 rgbyB = ((rgbyN2 + rgbyP2) * 0.25) + (rgbyA * 0.25);
|
|
/*--------------------------------------------------------------------------*/
|
|
#if (FXAA_GREEN_AS_LUMA == 0)
|
|
// TODO Luma
|
|
float lumaB = FxaaLuma(rgbyB);
|
|
#else
|
|
float lumaB = rgbyB.y;
|
|
#endif
|
|
if((lumaB < lumaMin) || (lumaB > lumaMax))
|
|
rgbyB.xyz = rgbyA.xyz * 0.5;
|
|
//
|
|
return rgbyB;
|
|
}
|
|
/*==========================================================================*/
|
|
|
|
uniform sampler2D f_color;
|
|
|
|
uniform vec2 screenSize;
|
|
|
|
#define edgeSharpness 7.0
|
|
#define edgeThreshold 0.1
|
|
#define edgeThresholdMin 0.005
|
|
|
|
void main(){
|
|
vec2 screenSize05 = 0.5 * screenSize;
|
|
|
|
vec4 posPos;
|
|
posPos.xy = pos;
|
|
posPos.zw = pos + screenSize;
|
|
|
|
vec4 rcpFrameOpt;
|
|
rcpFrameOpt.xy = -screenSize05;
|
|
rcpFrameOpt.zw = screenSize05;
|
|
|
|
fragColor = vec4(FxaaPixelShader(pos + screenSize05, posPos, f_color, rcpFrameOpt, rcpFrameOpt * 4.0, edgeSharpness, edgeThreshold, edgeThresholdMin).rgb, 1.0);
|
|
}
|